***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 31, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt 1K5SMCJ22CA 1 2 
.param
+vc0 = 2.073e-10	 vc1 = 3.682e-11	 vc2 = 4.057e-12	vc3 = 2.965e-1
+tc1 = 3.661e-2		 tc2 = 3.402e-2		 tc3 = 4.501e-2		tc4 = 2.072e-2
d1 1 c zener
g1 c 1 value = {(vc0+vc1*v(c,1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,1))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d2 2 c zener
g2 c 2 value = {(vc0+vc1*v(c,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,2))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1   
***** dc model parameter *****
+ is = 1e-13		   n = 1.0		  rs = 1e-2
+ibv = 1e-3		 nbv = 1.0		  bv = 25.5
***** capacitance parameter *****
+cjo = 1.389e-9		   m = 2.465e-1		  vj = 9.898e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.005		 xti = 3
+trs1 = 1e-4		tbv1 = 7.755e-4		tbv2 = -7.384e-7
.ends 1K5SMCJ22CA
*$
